Day/Night-Textures

[tompablo]

Hi!

Me and some other users and developers are still flying FS98!
Who can help me? I want to make different textures for day and
night for api-files or buildings. I have already downloaded the
SCASM-Help by M. Moldenhauer. The only thing I could see out
there from was the "28C"-line for this command. But I don't know
how to implement this into SCASM; also the different textures...
Thanks for your help!
If someone has a example-SCASM for me?

 

[arno]

Hi,

Could you post the line of code you mention?

I think you would have to use the IfVarRange command to check the 28C variable indeed and then use that to show different textures on the object.

 

[tompablo]

Hi Arno,

thanks for your reply!
Yes, I have already tried the "IfVar"-entry, but it did hung up
the Fs98...
Maybe I should send you the SCASM-file, if you should have the
right idea.
Could I send you this via email?

Thanks a lot

 

[arno]

Hi,

You can simply post the lines of code that you are trying to alter here on the site. Then I'll take a look.

 

[tompablo]

Oh there are few lines in here...
I try to take one "texture"-line out from this:


:L00D7DA
Points( 0
-60 0 -60 ; 0
60 0 -60 ; 1
60 0 60 ; 2
-60 0 60 ; 3
-60 80 -60 ; 4
60 80 -60 ; 5
60 80 60 ; 6
-60 80 60 ; 7
)
Bitmap( TermRJFR.pat 0 0 0 0 )
Concave
POverride
TexPoly( m 0 0 -32767 60
0 0 254 ; 0
4 0 84 ; 1
5 254 84 ; 2
1 254 254 ; 3
)
Return

 

[arno]

Did you try something like this?

:L00D7DA
Points( 0
-60 0 -60 ; 0
60 0 -60 ; 1
60 0 60 ; 2
-60 0 60 ; 3
-60 80 -60 ; 4
60 80 -60 ; 5
60 80 60 ; 6
-60 80 60 ; 7
)

IfVarRange( :nowinter 6F8 0 0 )
Bitmap( text_wi.pat 0 0 0 0 )
Jump( :seasonend )
:nowinter
IfVarRange( :nospring 6F8 1 1 )
Bitmap( text_sp.pat 0 0 0 0 )
Jump( :seasonend )
:nospring
IfVarRange( :nosummer 6F8 2 2 )
Bitmap( text_su.pat 0 0 0 0 )
Jump( :seasonend )
:nosummer
Bitmap( text_fa.pat 0 0 0 0 )
:seasonend

Concave
POverride
TexPoly( m 0 0 -32767 60
0 0 254 ; 0
4 0 84 ; 1
5 254 84 ; 2
1 254 254 ; 3
)
Return

 

[tompablo]

Your example seems to be for seasonal textures.
Do you have an example for day and night too?
Thanks again!

 

[arno]

Oops, that is what you get when you don't think while writing the code .

:L00D7DA
Points( 0
-60 0 -60 ; 0
60 0 -60 ; 1
60 0 60 ; 2
-60 0 60 ; 3
-60 80 -60 ; 4
60 80 -60 ; 5
60 80 60 ; 6
-60 80 60 ; 7
)

IfVarRange( :night 23C 1 1 )
Bitmap( text.pat 0 0 0 0 )
Jump( :nightend )
:night
Bitmap( text_lm.pat 0 0 0 0 )
:nightend

Concave
POverride
TexPoly( m 0 0 -32767 60
0 0 254 ; 0
4 0 84 ; 1
5 254 84 ; 2
1 254 254 ; 3
)
Return

This should show the night texture at dusk/dawn and night.

 

[tompablo]

Hi Arno,

thanks for your help!
But I want to be sure! Are this commands (also) for FS98?

 

[arno]

Yes, this should work in Fs98 as well. But it is almost 10 years ago that I made scenery for Fs98, so I am not 100% sure .

 

[tompablo]

Here is an outtake of the SCASM-description from M.Moldenhauer.
In brackets are entered the codes, first 28C, then space and then
1 for day, or 2 for dusk and 4 for night:

28C Time of day code
1 day
2 dusk/dawn
4 night

I will see for another example from day/night-scenery.
I will also try your version.

 

[tompablo]

Now with your example it always sets night texture, no day-texture.
But anyway it doesn't hung up FS98. There must be
another command in a bracket I think like 2 or 4 for dusk and night.

 

[tompablo]

Here is an outtake from Airports 2000 (Barcelona), where day- and
textures are included. This I had tried first, but I had problems
with the label-call L0001 example) at last entry.

Bitmap( ALDEASA.EBL 0 0 0 0 )
IfVarAnd( :L0006FE 028C 0004 )
Bitmap( ALDEASAN.EBL 0 0 0 0 )

 

[arno]

Hi,

The code is almost the same. I check if it is day (1) and they check if it is night (4). The other difference is that they use the IfVarAnd command to check a single value, while I used IfVarRange to check a range (where min and max value are the same now).

If you always see the night texture, it could mean that the Jump is performed correctly. Are you sure that you set all labels correct?

 

[tompablo]

Thank you so much, Arno!!
It seems I had a nervous breakdown...yesterday.
For some reason it works now with your example!!

Thanks again!

 

[arno]

Glad to hear everything work now . It is nice to know that I still know something about Fs98 scenery design as well .

 

[tompablo]

Hi Arno,

I have another problem going on, sorry!
Now I make objects with EOD, which including more pieces with
textures. With the "IfVAr"-command for every part or piece
I can't convert it (correctly) to BGL. It just beeps at SCASM-program and
the BGL shows strange objects in FS. How can I get a "global" command
for one texture in one object? The object (tower) has seven pieces.

Thanks!

 

[tompablo]

Here is the scasm-file with the one object:

 

[arno]

Hi,

The problem is that the labels you use should be unique. So you can not use the label :night multiple times in the same source. I guess it is best to put a number behind the label to make them unique again. So :night1 for the first Bitmap command, :night2 for the second, etc.

 

[tompablo]

Hi Arno, I think you see the smilies! THANK YOU!
I will have some other questions for other things.
But I will inform you in this case.